Module VI:  File handling

You millennials, gen z’s, and gen alphas grew up in the unfortunate era in which files are saved to a location that is often nebulous and undefined.  Take control of your computer.  Organize your files according to your needs rather than the whims of whatever programmer programmed the last app you are using.  Start your macro recorder and open any image on your computer.  The resulting string argument of the open command is usually referred to as the pathname of the image, for example:

"C:/Folder1/Folder2/Folder3 /TestImage.gif"

In this case TestImage.gif is in Folder3, which is in Folder2, which is in Folder1, which is in the C: drive.  In order to get the pathname for a particular folder, we will use the getDirectory function:

pathname=getDirectory("Please choose a directory");

print(pathname);

When you run this code, it should prompt you to choose a directory and then print out the pathname of the directory you chose.  Now define a filename and print to that file:

fname="test.txt";

//f is an ID number that points to the file, a file handle

f=File.open(pathname+fname);

//Print to file f

print(f,"Hello");

//You need to close your file or it won't be released for you to view

File.close(f);

 

Its easy!  Take a look at the file.  If you are running a PC operating system, there is another issue we need to address – escape sequences.  In a PC, the designated folder separator is usually a backslash, whereas in Unix and Mac operating systems, it is instead a forward slash.  But backslashes have other meanings as well, they code for special characters.  To learn some of them, print the following lines to your file and see how these different lines printed. 

//Note that "\t" means tab

print(f,"1\t2\t3");

//To actually print a "\", you need to put a "\\" into the print statement

print(f,"1\\t2\\t3");

//A newline is "\n"

print(f,"1\n2\n3");

 

Be aware of escape sequences if you are running a PC and having problems defining a pathname!

Module V Exercise:  Data from Ball Motion Stills

 

In the last module exercise, we learned how to determine the centroid of a ball moving within an image stack.  We will now do the same thing for still images within a folder, and write the X and Y coordinates to a data file.  Unzip the 9 test images into a BallMotionStills directory.

 

First lets just try printing the names of all the images.  The getDirectory command will prompt the user to choose the directory where the images are located.  The getFileList command will return a string array of all the filenames in that directory.  Then you will loop through and print the names of the images in the directory.

 

imageDirectory=getDirectory("Where are the images located?");

fileList=getFileList(imageDirectory);

for (i = 0; i < fileList.length; i++) {

               print(fileList[i]);

}

 

Now that we have a handle to all the images, we will locate the X and Y positions of the ball exactly like we did in the previous module.  However since we have separate images, we will need to open and close each image individually:

 

run("Set Measurements...", "centroid redirect=None decimal=0");

imageDirectory=getDirectory("Where are the images located?");

fileList=getFileList(imageDirectory);

X=newArray(fileList.length);

Y=newArray(fileList.length);

 

for (i = 0; i < fileList.length; i++) {

               open(imageDirectory+fileList[i]);

               run("Find Maxima...", "prominence=10 output=[Point Selection]");

               run("Measure");

               X[i]=getResult("X");

               Y[i]=getResult("Y");

               close();

}

 

Now we only have to add code to write those X and Y values to a data file.  We will open a data file, write all the values and close it again.  (Note when choosing the directory for the data file, do not choose the folder with the images, because then if you run the code again, it will think your data file is an image and cause an error.  We have tried to keep everything simple and not done any checking to determine if the images are actually images.)  Go ahead and add this code and run everything together.

 

dataDirectory=getDirectory("Where should the data file be located?");

f=File.open(dataDirectory+"data.txt");

tab="\t";

print(f,"filename"+tab+"X"+tab+"Y");

for (i = 0; i < fileList.length; i++) {

               print(f,fileList[i]+tab+X[i]+tab+Y[i]);

}

File.close(f);

 

Now take a look at your file.  Hopefully you have data!